ESP32-CAMのCameraWebServerを解析してみる（その2）撮影画像のhttp転送

その１の続きです！

撮影した画像をSDカードに記録せず、http転送してみたいと思います。💪

ベースとなるCameraWebServerはかなりシェイプしたので、すごく分かりやすくなったと思います。

プログラムが短くなってのでファイルを１つにまとめてもよかったのですが、

CameraWebSever.ino
add_httpd.cpp
camera_pins.h

の３つのファイルになっています。

１、CameraWebServer.ino

カメラの初期設定、WIFIの初期設定、httpServerの設定をしてloop処理で待っているだけです。

#include <esp_camera.h>
#include <WiFi.h>
#include <ESPmDNS.h>
#include "camera_pins.h"
const char* ssid = "your ssid";
const char* password = "your password";
void startCameraServer();
void setup() {
 Serial.begin(115200);
 Serial.setDebugOutput(true);
 Serial.println();
 camera_config_t config;
 config.ledc_channel = LEDC_CHANNEL_0;
 config.ledc_timer = LEDC_TIMER_0;
 config.pin_d0 = Y2_GPIO_NUM;
 config.pin_d1 = Y3_GPIO_NUM;
 config.pin_d2 = Y4_GPIO_NUM;
 config.pin_d3 = Y5_GPIO_NUM;
 config.pin_d4 = Y6_GPIO_NUM;
 config.pin_d5 = Y7_GPIO_NUM;
 config.pin_d6 = Y8_GPIO_NUM;
 config.pin_d7 = Y9_GPIO_NUM;
 config.pin_xclk = XCLK_GPIO_NUM;
 config.pin_pclk = PCLK_GPIO_NUM;
 config.pin_vsync = VSYNC_GPIO_NUM;
 config.pin_href = HREF_GPIO_NUM;
 config.pin_sscb_sda = SIOD_GPIO_NUM;
 config.pin_sscb_scl = SIOC_GPIO_NUM;
 config.pin_pwdn = PWDN_GPIO_NUM;
 config.pin_reset = RESET_GPIO_NUM;
 config.xclk_freq_hz = 20000000;
 config.pixel_format = PIXFORMAT_JPEG;
 config.frame_size = FRAMESIZE_SVGA;
 config.jpeg_quality = 12;
 config.fb_count = 1;
 // camera init
 esp_err_t err = esp_camera_init(&config);
 if (err != ESP_OK) {
   Serial.printf("Camera init failed with error 0x%x", err);
   return;
 }
 WiFi.begin(ssid, password);
 while (WiFi.status() != WL_CONNECTED) {
   delay(500);
   Serial.print(".");
 }
 Serial.println("");
 Serial.println("WiFi connected");
 startCameraServer();
 Serial.print("Camera Ready! Use 'http://");
 Serial.print(WiFi.localIP());
 Serial.println("' to connect");
 /*if (MDNS.begin("esp32cam")) {
   Serial.println("MDNS responder started");
 }
/**/
}
void loop() {
 // put your main code here, to run repeatedly:
 delay(10000);
}

解像度、クオリティーを変えたい場合は下記の部分を変更します。config.frame_sizeを変更すれば解像度が変わります。下記はSVGAになっているので800×600ということです。

config.frame_size = FRAMESIZE_SVGA;
 config.jpeg_quality = 12;
 config.fb_count = 1;

mDNSの設定はコメントにしてありますが、コメントアウトすればmDNSが使えます。コメントにした理由は、mDNSを使うと転送に時間がかかると感じたからです。IPアドレスでアクセスした方が、転送がはるかに速いようです。

/*if (MDNS.begin("esp32cam")) {
   Serial.println("MDNS responder started");
 }
/**/

2、add_httpd.cpp

こちらは非常にすっきりしたと思います。

初期設定でhttpアクセスがあった場合の処理を登録して、httpアクセスがあった場合、画像を撮影し、撮影したJPEGデータをhttpでバイナリー転送しています。

#include <esp_http_server.h>
#include <esp_camera.h>
#include <Arduino.h>
httpd_handle_t camera_httpd = NULL;
static esp_err_t capture_handler(httpd_req_t *req){
   camera_fb_t * fb = NULL;
   esp_err_t res = ESP_OK;
   int64_t fr_start = esp_timer_get_time();
//画像の取り込み
   fb = esp_camera_fb_get();
   if (!fb) {
       Serial.println("Camera capture failed");
       httpd_resp_send_500(req);
       return ESP_FAIL;
   }
   httpd_resp_set_type(req, "image/jpeg");
   Serial.println(fb->width);
 
       size_t fb_len = 0;
           fb_len = fb->len;
           res = httpd_resp_send(req, (const char *)fb->buf, fb->len);
       esp_camera_fb_return(fb);
       int64_t fr_end = esp_timer_get_time();
       Serial.printf("JPG: %uB %ums\n", (uint32_t)(fb_len), (uint32_t)((fr_end - fr_start)/1000));
       return res;
}
void startCameraServer(){
   httpd_config_t config = HTTPD_DEFAULT_CONFIG();
   httpd_uri_t capture_uri = {
       .uri       = "/",
       .method    = HTTP_GET,
       .handler   = capture_handler,
       .user_ctx  = NULL
   };
   Serial.printf("Starting web server on port: '%d'\n", config.server_port);
   if (httpd_start(&camera_httpd, &config) == ESP_OK) {
       httpd_register_uri_handler(camera_httpd, &capture_uri);
   }
}

３、camera_pins.h

これはPINアサインの定義のみです。

#define PWDN_GPIO_NUM     32
#define RESET_GPIO_NUM    -1
#define XCLK_GPIO_NUM      0
#define SIOD_GPIO_NUM     26
#define SIOC_GPIO_NUM     27
#define Y9_GPIO_NUM       35
#define Y8_GPIO_NUM       34
#define Y7_GPIO_NUM       39
#define Y6_GPIO_NUM       36
#define Y5_GPIO_NUM       21
#define Y4_GPIO_NUM       19
#define Y3_GPIO_NUM       18
#define Y2_GPIO_NUM        5
#define VSYNC_GPIO_NUM    25
#define HREF_GPIO_NUM     23
#define PCLK_GPIO_NUM     22

４、まとめ

CameraWebSeverはかなり難解なソフトでしたが、バラバラにしてみていろいろ勉強になりました。💮

まだまだ勉強の余地があるソースですので、別の機能も抜き出してみたいと思います。次はストリーミングかな？

では🤚