ストキャスティクスインジケーター(アラート機能付き)【TradingView】
スクリーンショット_2019-04-28_18_12_07

ストキャスティクスインジケーター(アラート機能付き)【TradingView】

まっつ(TORYS)@matsu_bitmex

無料で使えるストキャスティクス(アラート付き)インジを公開しました。


こんにちは、まっつ@matsu_bitmex です。アラート付きストキャスを作って欲しい、とのご要望を頂き作成しました。


TradingViewにて 「Stochastic with alert」と検索していただくと使えます。


◯ インジの特徴紹介

普通のストキャスとして使えます。


%K、%D、Slow%Dの3本のラインが表示できます。


トレンドによって背景色が付きます。

MA3本がパーフェクトオーダーでトレンド判定としています。MAはSMA/EMA切り替え可能です。

EMAの場合は EMA? にチェックを入れてください。


トレンド発生中、ストキャスが一定のラインより外側でクロスしたタイミングでサインが発生します。押し目買い・戻り売りのサインとして使用可能。

一定のラインとは上下のライン。編集可能。


%Kの平滑化はSMAとEMAで選択可能。

↑SMA ↓EMA

SMAの方がなめらか。EMAの方が反応が早い、です。

EMAにしたい場合は Smooth EMA? にチェックを入れてください。


上位足のストキャス表示ができます。

1時間足に4時間足のストキャスを表示させて上下に並べてみたよ、って感じです。原理としては1時間足の80SMAは4時間足の20SMAに相当するよね、という感じで近似しています。ローソク足の本数など変わってくるので完璧に一致とはいきませんが、それなりに似たものにはなっているかな、と。

後ろに Mult って付いてる2本がそれです。

設定の Multiplier で調節してください。デフォルトでは 4倍 表示になっているので15分足に対して1時間足、1時間足に対して4時間足、といった感じになっています。1分足に対して5分足のストキャスを表示したい場合は Multplier を 5 に変更してください。


◯ アラート設定

upper lineってなってるところは何でもいいです。気にせずに。

1. 押し目買い&戻り売りアラート(緑丸&赤丸のポイント)
2. 押し目買いアラート(緑丸のポイント)
3. 戻り売りアラート(赤丸のポイント)

の3種類となっています。お好みでどうぞ。


◯ ソースコード

//@version=3
study(title="Stochastic with alert", shorttitle="Stoch", precision=1)

// stochastic -----
smooth_ma = input(false, "smooth EMA?")
periodK = input(14, title="K length", minval=1)
periodD = input(3, title="D length", minval=1)
smoothK = input(3, title="Smooth length", minval=1)
mult = input(4, "multiplier")

k = stoch(close, high, low, periodK)
d = smooth_ma ? ema(k, smoothK) : sma(k, smoothK)
sd = smooth_ma ? ema(d, periodD) : sma(d, periodD)

k_mult = stoch(close, high, low, periodK * mult) 
d_mult = smooth_ma ? ema(k_mult, smoothK * mult) : sma(k_mult, smoothK * mult) 
sd_mult = smooth_ma ? ema(d_mult, periodD * mult) : sma(d_mult, periodD * mult) 

upper = input(80, "upper line")
lower = input(20, "lower line")
p_u = plot(upper, "upper line", silver)
p_l = plot(lower, "lower line", silver)
plot(50, "center line", silver)
fill(p_u, p_l, silver, 90, "fill")

// MA -----
ma_select = input(true, "EMA?")
ma_src = input(close, "MA source")
ma_len1 = input(15, "MA length 1", minval=1)
ma_len2 = input(25, "MA length 2", minval=2)
ma_len3 = input(75, "MA length 3", minval=3)

ma1 = ma_select ? ema(ma_src, ma_len1) : sma(ma_src, ma_len1)
ma2 = ma_select ? ema(ma_src, ma_len2) : sma(ma_src, ma_len2)
ma3 = ma_select ? ema(ma_src, ma_len3) : sma(ma_src, ma_len3)

trend_up = ma1 > ma2 and ma2 > ma3
trend_down = ma1 < ma2 and ma2 < ma3
bgcolor(trend_up ? #32cd32 : trend_down ? red : na, title="trend bgcolor")

// plot Stoch -----
plot(sd_mult, "Slow%D mult", orange)
plot(d_mult, "%D mult", #0094ff, 2, transp=0)
//plot(k_mult, "%K mult", yellow)

plot(sd, "Slow%D", orange, 2)
plot(d, "%D", #0094ff, 3, transp=0)
plot(k, "%K", yellow)

// GC/DC -----
gc = crossover(d, sd) and sd <= lower and trend_up
dc = crossunder(d, sd) and sd >= upper and trend_down

plot(d, "GC/DC", gc ? lime : dc ? red : na, 4, circles)

// alert -----
alertcondition(gc or dc, "1. alert cross", "cross")
alertcondition(gc, "2. alert GC", "GC")
alertcondition(dc, "3. alert DC", "DC")


◯ まとめ

というわけで、簡単ではありましたがアラート付きストキャスの紹介でした。よかったらnoteのフォロー・スキ・オススメよろしくお願いします。

また、インジの作成承っておりますのでお気軽に連絡ください。(note経由での連絡は気付くのが遅くなり…すみませんが、Twitter経由で連絡いただけると助かります。)

最後まで読んでいただきありがとうございました。ではまた次のnoteで!

この記事が気に入ったら、サポートをしてみませんか?
気軽にクリエイターの支援と、記事のオススメができます!
スキありがとうございます!
まっつ(TORYS)@matsu_bitmex
Tradingview Pine スクリプトで開発やってます。BTCFX/為替で使えるインディケーター公開中。noteは有料にしてますがインジは全て無料で使用可能。ぜひ使ってみてください。インジ制作のご相談お気軽に。※ 連絡はTwitter DMでお願いします ※