見出し画像

高校数学をプログラミングで解く（数学I編）「1-1 関数とグラフ」

MK's papa

はじめに

今回は、数学Iで学ぶ「関数とグラフ」について、１次関数と２次関数のグラフを描くプログラムや２次関数の最小値を求めるプログラムなどを作成します。

１次関数のグラフを描く

まず、１次関数

$$
y=\frac{1}{2}x+1
$$

のグラフを描きます。

１次関数をプログラムの関数として準備

１次関数をプログラムの関数として準備します。関数化については記事『高校数学をプログラミングで解く（準備編）「3-2 関数の作成」』で解説しています。

// 一次関数の関数
float linearfunction(
  float x
){
  return 1.0/2.0 * x + 1.0;
}

ソースコード1　１次関数$${y=\frac{1}{2}x+1}$$の関数

１次関数のグラフを描く

記事『高校数学をプログラミングで解く（数学I編）「1-0-1 グラフを描くための準備（その1）」』及び『高校数学をプログラミングで解く（数学I編）「1-0-2 グラフを描くための準備（その2）」』で説明したグラフの描画方法を利用して、１次関数のグラフを描いてみます。
スケッチ「drawLinearFunction」を準備し、その「drawLinearFunction」フォルダに「setAxes.pde」ファイルをコピーします。このとき、スケッチ「drawLinearFunction」の開発環境ウィンドウは図1のように、タブ欄に「setAxes」タブが追加された形になります。

図1　スケッチ「drawLinearFunction」の開発環境ウィンドウ

これにより、「setAxes.pde」ファイルに記述したsetAxes関数を利用することができるようになります。
では、１次関数を描くプログラムを準備します。

// １次関数のグラフを描く
void setup(){
  size(500,500);
  noLoop();
  float x_range = 10.0; // x軸の表示範囲 -x_rangeからx_rangeまで
  float y_range = 10.0; // y軸の表示範囲 -y_rangeからy_rangeまで 
  setAxes(x_range, y_range); // 座標軸の準備
  
  noFill();
  stroke(0,0,0);
  
  // グラフの定義域
  float x_l = -x_range; // 定義域の左端
  float x_r = x_range; // 定義域の右端
  int plot_num = 200; // グラフを描くための頂点の個数  
  
  // グラフを描画
  float x, y; // 関数の座標
  float X, Y; // キャンバス上の座標 
  beginShape();
  for(int i=0; i<=plot_num; i++){
    x = x_l + (x_r - x_l) / plot_num * i; // 関数のx座標
    y = linearfunction(x); // 関数の値
    // キャンバス上の座標位置に換算
    X = width / 2.0 / x_range * x;
    Y = height / 2.0 / y_range * y;
    vertex(X, Y);
  }
  endShape();
  
}

// １次関数の関数
float linearfunction(
  float x
){
  return 1.0/2.0 * x + 1.0;
}

ソースコード2　１次関数$${y=\frac{1}{2}x+1}$$を描くプログラム

このソースコード2を、スケッチ「drawLinearFunction」の
「drawLinearFunction」タブのテキストエディタ部分に書きます（図2）。

図2　「drawLinearFunction」タブのテキストエディタにソースコード2を記述

これを実行すると、図3のように、実行ウィンドウのキャンバス上に$${-10 \leq x \leq 10}$$の定義域に対して１次関数$${y=\frac{1}{2}x+1}$$のグラフを描きます。

図3　１次関数のグラフ

２次関数のグラフを描く

次に、２次関数

$$
y=x^2+4x+3
$$

のグラフを描きます。

２次関数をプログラムの関数として準備

２次関数をプログラムの関数として準備します。

// ２次関数の関数
float quadraticfunction(
  float x
){
  return x*x + 4.0*x + 3.0;
}

ソースコード3　２次関数$${y=x^2+4x+3}$$の関数

２次関数のグラフを描く

スケッチ「drawQuadraticFunction」を準備し、その「drawQuadraticFunction」フォルダに「setAxes.pde」ファイルをコピーします。その上で、２次関数を描くプログラムを準備します。

// ２次関数のグラフを描く
void setup(){
  size(500,500);
  noLoop();
  float x_range = 10.0; // x軸の表示範囲 -x_rangeからx_rangeまで
  float y_range = 10.0; // y軸の表示範囲 -y_rangeからy_rangeまで 
  setAxes(x_range, y_range); // 座標軸の準備
  
  noFill();
  stroke(0,0,0);
  
  // グラフの定義域
  float x_l = -x_range; // 定義域の左端
  float x_r = x_range; // 定義域の右端
  int plot_num = 200; // グラフを描くための頂点の個数  
  
  // グラフを描画
  float x, y; // 関数の座標
  float X, Y; // キャンバス上の座標 
  beginShape();
  for(int i=0; i<=plot_num; i++){
    x = x_l + (x_r - x_l) / plot_num * i; // 関数のx座標
    y = quadraticfunction(x); // 関数の値
    // キャンバス上の座標位置に換算
    X = width / 2.0 / x_range * x;
    Y = height / 2.0 / y_range * y;
    vertex(X, Y);
  }
  endShape();
  
}

// ２次関数の関数
float quadraticfunction(
  float x
){
  return x*x + 4.0*x + 3.0;
}

ソースコード4　２次関数$${y=x^2+4x+3}$$を描くプログラム

このソースコード4を、スケッチ「drawQuadraticFunction」の
「drawQuadraticFunction」タブのテキストエディタ部分に書きます（図4）。

図4　「drawQuadraticFunction」タブのテキストエディタにソースコード4を記述

これを実行すると、図5のように、実行ウィンドウのキャンバス上に$${-10 \leq x \leq 10}$$の定義域に対して２次関数$${y=x^2+4x+3}$$のグラフを描きます。なお、縦方向の表示範囲が$${-10 \leq y \leq 10}$$となっていますので、$${y>10}$$の範囲のグラフは表示されません。

図5　２次関数のグラフ

関数の最大値と最小値

最後に、２次関数$${y=x^2+4x+3}$$の定義域$${-10 \leq x \leq 10}$$での最小値を、プログラムを作ってもとめてみます。

アルゴリズム設計

① 最小値を格納するfloat型の変数$${y_{\mathrm{min}}}$$を準備し、できるだけ大きな値（今回は表示範囲の最大値$${10}$$としています）で初期化しておきます。
② 定義域$${-10 \leq x \leq 10}$$をplot_num個に分割し、小さい方から順にその$${x}$$での関数の値をもとめ、その関数の値が$${y_{\mathrm{min}}}$$の値より小さければ、$${y_{\mathrm{min}}}$$をその時の関数の値で更新します。
③ 定義域全体で②を行った結果、最後に残った$${y_{\mathrm{min}}}$$の値が最小値となります。

最小値を求めるプログラム

上記のアルゴリズムをもとに、２次関数の最小値を求めるプログラムを作成します。

// ２次関数の最小値を求める
void setup(){

  float x_range = 10.0; // x軸の表示範囲 -x_rangeからx_rangeまで
  float y_range = 10.0; // y軸の表示範囲 -y_rangeからy_rangeまで 

  // グラフの定義域
  float x_l = -x_range; // 定義域の左端
  float x_r = x_range; // 定義域の右端
  int plot_num = 200; // グラフを描くための頂点の個数  
  
  // グラフを描画
  float x, y; // 関数の座標
  float y_min = y_range; // 最小値 表示範囲の最大値で初期化
  float x_min = 0.0; // 関数が最小値を取るときのxの値
  for(int i=0; i<=plot_num; i++){
    x = x_l + (x_r - x_l) / plot_num * i; // 関数のx座標
    y = quadraticfunction(x); // 関数の値
    if( y_min > y ){
      y_min = y;
      x_min = x;
    }
  }
  println(x_min, y_min);

}

// ２次関数の関数
float quadraticfunction(
  float x
){
  return x*x + 4.0*x + 3.0;
}

ソースコード5　２次関数$${y=x^2+4x+3}$$の最小値を求めるプログラム

このソースコード5を、Processingの開発環境ウィンドウを開いて（スケッチ名を「minQuadraticFunction」としています）、テキストエディタ部分に書いて実行すると、図6のように、コンソールに$${-2.0 -1.0}$$と表示されます。これは２次関数$${y=x^2+4x+3}$$の最小値が$${-1}$$でそのときの$${x}$$の値が$${-2}$$となることを示しています。

図6　スケッチ「minQuadraticFunction」の実行結果

なお、今回は2次関数$${y=x^2+4x+3}$$が下に凸のグラフになるため、最小値を求めましたが、最大値を求めたい場合も同様な方法で求めることができます。

グラフに最小値をプロットするプログラム

おまけとして、２次関数$${y=x^2+4x+3}$$のグラフに最小値の点をプロットするプログラムを作成します。それには、２次関数を描くプログラム（ソースコード4）に、２次関数の最小値を求めるプログラム（ソースコード5）を組み込んでいきます。

// ２次関数のグラフと最小値を描く
void setup(){
  size(500,500);
  noLoop();
  float x_range = 10.0; // x軸の表示範囲 -x_rangeからx_rangeまで
  float y_range = 10.0; // y軸の表示範囲 -y_rangeからy_rangeまで 
  setAxes(x_range, y_range); // 座標軸の準備
  
  noFill();
  stroke(0,0,0);
  
  // グラフの定義域
  float x_l = -x_range; // 定義域の左端
  float x_r = x_range; // 定義域の右端
  int plot_num = 200; // グラフを描くための頂点の個数  
  
  // グラフを描画
  float x, y; // 関数の座標
  float X, Y; // キャンバス上の座標
  float y_min = y_range; // 最小値 表示範囲の最大値で初期化
  float x_min = 0.0; // 関数が最小値を取るときのxの値
  beginShape();
  for(int i=0; i<=plot_num; i++){
    x = x_l + (x_r - x_l) / plot_num * i; // 関数のx座標
    y = quadraticfunction(x); // 関数の値
    if( y_min > y ){
      y_min = y;
      x_min = x;
    }
    // キャンバス上の座標位置に換算
    X = width / 2.0 / x_range * x;
    Y = height / 2.0 / y_range * y;
    vertex(X, Y);
  }
  endShape();
  
  // 最小値を取るグラフ上の点をキャンバス上の座標位置に換算してプロット
  stroke(255,0,0);
  strokeWeight(5);
  float X_min, Y_min;
  X_min = width / 2.0 / x_range * x_min;
  Y_min = height / 2.0 / y_range * y_min;
  point(X_min, Y_min);

}

// ２次関数の関数
float quadraticfunction(
  float x
){
  return x*x + 4.0*x + 3.0;
}

ソースコード6　２次関数のグラフとその最小値を描くプログラム

スケッチ「drawQuadraticFunctionwithMin」を準備し、その「drawQuadraticFunctionwithMin」フォルダに「setAxes.pde」ファイルをコピーします。その上で、このソースコード6を、スケッチ「drawQuadraticFunctionwithMin」の
「drawQuadraticFunctionwithMin」タブのテキストエディタ部分に書いて実行すると、図7のように、２次関数のグラフが描かれ、その最小値を取る点が赤色で描かれます。

図7　２次関数のグラフとその最小値

まとめ

今回は、数学Iで学ぶ「関数とグラフ」について、１次関数と２次関数のグラフを描くプログラムや２次関数の最小値を求めるプログラムなどを作成しました。
記事『高校数学をプログラミングで解く（数学I編）「1-0-2 グラフを描くための準備（その2）」』で導入した座標軸を描くための関数setAxesを利用する方法を復習しながら描いてみました。このようにプログラムを作成する際は以前作成したプログラムを関数化して再利用すると便利ですし、また間違いを少なくすることもできます。このような関数化して再利用することに慣れていってください。

参考文献

改訂版 教科書傍用 スタンダード 数学I（数研出版、ISBN9784410209178）

この記事が気に入ったらサポートをしてみませんか？