見出し画像

左人差し指と右人差し指が対決する早押しゲーム

自分の左人差し指と右人差し指のどちらが早くキーを押せるのかを競うひどいゲームです。

// 左人差し指と右人差し指が対決する早押しゲーム

// プログラミング言語「ドリトル」

// インストール版ドリトルで実行してください。

// 2020.06.26 蕪木 孝


早押し = 0。

左指 = ボタン ! "" "ESCAPE" 作る。
左指 ! 消える。
左指 : 動作 = 「
	「:早押し == 0」 ! なら 「:早押し = -10」
	そうでなければ 「:早押し == 1」 なら 「:早押し = 10」 実行。
」。

右指 = ボタン ! "" "ENTER" 作る。
右指 ! 消える。
右指 : 動作 = 「
	「:早押し == 0」 ! なら 「:早押し = -20」
	そうでなければ 「:早押し == 1」 なら 「:早押し = 20」 実行。
」。

ラベル1 = ラベル ! 作る。
ラベル1 ! "ESC と ENTER にゆびをおけ" 書く    -198 12 位置。

タイマー1 = タイマー ! 作る    1秒 間隔    10 回数。
タイマー1 ! 「
	| i |

	「:早押し == -10」 ! なら 「
		:早押し = 2。
		ラベル1 ! "フライングで ひだり の まけ" 書く    -162 12 位置。
	」
	そうでなければ 「:早押し == -20」 なら 「
		:早押し = 2。
		ラベル1 ! "フライングで みぎ の まけ" 書く    -150 12 位置。
	」 実行。

	「:早押し != 2」 ! なら 「
		「ぜんぶ ! (i >= 3) (i <= 5) 本当」 ! なら 「
			ラベル1 ! (6 - i) 書く    -12 12 位置。
		」
		そうでなければ 「i == 6」 なら 「
			「:早押し == 0」 ! なら 「:早押し = 1」 実行。
			ラベル1 ! "押せ" 書く    -24 12 位置。
		」
		そうでなければ 「i == 7」 なら 「
			「:早押し == 1」 ! なら 「
				:早押し = 2。
				ラベル1 ! "おそい" 書く    -36 12 位置。
			」
			そうでなければ 「:早押し == 10」 なら 「
				ラベル1 ! "ひだり の かち" 書く    -84 12 位置。
			」
			そうでなければ 「:早押し == 20」 なら 「
				ラベル1 ! "みぎ の かち" 書く    -72 12 位置。
			」 実行。
		」
		そうでなければ 「i == 10」 なら 「
			ラベル1 ! "よかったな" 書く    -60 12 位置。
		」 実行。
	」 実行。
」 実行。

実行方法

これは教育用プログラミング言語「ドリトル」で書いたプログラムです。
インストール版ドリトルを以下のサイトからダウンロードしてください。
https://dolittle.eplang.jp/download
パソコンのOSがWindowsなら「Windows用」をクリックするとダウンロードがはじまります。
ダウンロードしたら解凍してください。
解凍したら dolittle.bat をダブルクリックするとドリトルが起動します。
プログラムを貼り付けて「実行!」をクリックするとゲームスタートです。


世界中を探せば一人ぐらいはこれに熱狂する人がいるわけで。
そう考えるとこの世は面白いと思います。

この記事が気に入ったら、サポートをしてみませんか?
気軽にクリエイターの支援と、記事のオススメができます!
はい
2
モノづくり施設 DMM.make AKIBA を拠点として活動しているメイカーです。