高校数学１０分プログラミング（43日目、2024年7月31日）解説

本日の課題、おつかれさまでした。

整数$${M}$$と$${N}$$の最大公約数を求める関数 getGCD や整数$${M}$$と$${N}$$の最小公倍数を求める関数 getLCM を作成することができたでしょうか。

解答例

整数$${M}$$と$${N}$$の最大公約数を求める関数 getGCD や整数$${M}$$と$${N}$$の最小公倍数を求める関数 getLCM 及びそれらの関数を利用して$${M=12}$$と$${N=30}$$の最大公約数や最小公倍数を求め、コンソールに出力するプログラムの例は以下のようになります。

// 整数MとNの最大公約数や最小公倍数を求める関数
void setup(){
  // 整数M,N（ただし、2以上の整数）
  int M, N;
  M = 12;
  N = 30;
  
  // MとNのうち、大きい方を整数N_gtとし、N_gt以下の素数を求める
  int N_gt;
  if( M > N ){
    N_gt = M;
  } else {
    N_gt = N;
  }  
  // N_gt以下の素数を求める
  ArrayList<Integer> prime_numbers = getPrimeFactors(N_gt);
  
  // 最大公約数を求める
  int GCD = getGCD(M,N,prime_numbers);
  println("最大公約数:",GCD);
  int LCM = getLCM(M,N,prime_numbers);
  println("最小公倍数:",LCM);
}

// 整数N以下の素数を求める関数
ArrayList<Integer> getPrimeFactors(
  int N // 2以上の整数
){
  // int型の可変配列を準備する
  ArrayList<Integer> prime_numbers = new ArrayList<Integer>();
  // 最初の素数2を可変配列に追加
  prime_numbers.add(2);
 
  boolean pn_flag; // 素数かどうかのフラグ
  // 3以上N以下の整数について素数であるかを確認する
  for(int n=3; n<=N; n++){
    pn_flag = true;
    for(int m=2; m<n; m++){
      if( n%m == 0 ){ // mで割り切れたらnは素数でない
        pn_flag = false;
      }
    }
    if(pn_flag){
      prime_numbers.add(n); // iが素数と判定された場合、可変配列に追加
    }
  }
  
  return prime_numbers;
}

// 素因数分解を行う関数
ArrayList<Integer> primefactorization(
  int N, // 2以上の整数
  ArrayList<Integer> prime_numbers // N以下の素数
){
  // 素因数分解したときの各冪に対する指数
  ArrayList<Integer> exponents = new ArrayList<Integer>();
  
  // 整数Nを素因数分解する
  boolean divisible_flag; // 割り切れたかどうかを判定するフラグ
  int quotient = N; // 素数で割ったときの商
  int pn; // 素数を代入する変数
  int exponent_count;
  for(int i=0; i<prime_numbers.size(); i++){
    pn = prime_numbers.get(i); // i番目の素数を取り出す
    divisible_flag = true;
    exponent_count = 0;
    while(divisible_flag){
      if( quotient % pn == 0 ){ // 商が素数pnで割り切れた場合
        exponent_count++; // pnに対する指数の値を1増やす
        quotient = quotient / pn; // 商を更新する
      } else { // 素数pnがNの素因数ではない、またはpnがNの素因数としてすべて算出された場合
        divisible_flag = false; 
      }
    }
    exponents.add(exponent_count);
  } 
  
  return exponents;
}

// 整数MとNの最大公約数を求める関数
int getGCD(
  int M,
  int N,
  ArrayList<Integer> prime_numbers
){
  // M, Nをそれぞれ素因数分解する
  ArrayList<Integer> exponents_M = primefactorization(M, prime_numbers);
  ArrayList<Integer> exponents_N = primefactorization(N, prime_numbers);

  // MとNの最大公約数を求める
  float GCD = 1.0; // 最大公約数
  int exponents_GCD; // 最大公約数を素因数分解した時のi番目の冪の指数
  for(int i=0; i<prime_numbers.size(); i++){
    if( exponents_M.get(i) < exponents_N.get(i)){
      exponents_GCD = exponents_M.get(i);
    } else {
      exponents_GCD = exponents_N.get(i);
    }
    GCD = GCD * pow(prime_numbers.get(i), exponents_GCD);
  }
  
  return (int)GCD;
}

// 整数MとNの最小公倍数を求める関数
int getLCM(
  int M,
  int N,
  ArrayList<Integer> prime_numbers
){
  // M, Nをそれぞれ素因数分解する
  ArrayList<Integer> exponents_M = primefactorization(M, prime_numbers);
  ArrayList<Integer> exponents_N = primefactorization(N, prime_numbers);

  // MとNの最小公倍数を求める
  float LCM = 1.0; // 最小公倍数
  int powers_LCM; // 最小公倍数を素因数分解した時のi番目の冪の指数
  for(int i=0; i<prime_numbers.size(); i++){
    if( exponents_M.get(i) < exponents_N.get(i)){
      powers_LCM = exponents_N.get(i);
    } else {
      powers_LCM = exponents_M.get(i);
    }
    LCM = LCM * pow(prime_numbers.get(i), powers_LCM);
  }
  
  return (int)LCM;
}

ソースコード2　関数を利用して最大公約数や最小公倍数を求めて、結果をコンソールに出力するプログラム（完成版）

Processing の開発環境ウィンドウを立ち上げて、そのテキストエディタ部分にソースコード2を書き写し、実行ボタン（左上の ▶ ボタン）を押すと、コンソールに、

最大公約数: 6
最小公倍数: 60

と出力されます（図1）。

図1　最大公約数と最小公倍数がコンソールに出力される

やってほしいこと

今回作成した getGCD 関数や getLCM 関数の返り値は、

return (int)GCD;

などと記述しています。これは、float型からint型へのキャストという処理を行っています。キャストについては、記事『高校数学をプログラミングで解く（数学A編）「1-5 事象と確率」』のプログラムの解説2「キャスト」の節で解説していますので、一度読んでおいてください。

本日は以上です。
明日は、互いに素となる自然数の個数を数えるプログラムについて考えていきたいと思います。

明日もよろしくお願いします。

※今回の課題とその解答例について質問や疑問がある方は、本記事の下部にあるコメント欄からお願いします。

MK’s papa