【競馬】Publisher VBA で JRA-VAN DataLab. のデータを取得する

Publisher VBA で JV-Link を操作することにより、JRA-VAN DataLab. が提供する競馬データを取得することができます。

今回は Publisher を使って簡単な競馬ソフトを作りたいと思います。
※ Publisher は 32bit 版を使用して下さい。64bit 版では JV-Link が使えません。

Publisher VBA はバグがあるようで、Excel など他のソフトの VBA とは微妙に挙動が違います。そのため少し作り方を変えています。

1. 事前準備

事前準備に関してはこちらの記事を参照して下さい。

2. 作成手順

Publisher で新規の白紙を作成し、適当な名前で保存します。

[開発] タブの [Visual Basic] をクリックします。

Microsoft Visual Basic for Applications の画面が開きます。

[挿入] > [ユーザーフォーム] をクリックします。

ユーザーフォームが追加されます。
オブジェクト名はデフォルトの [UserForm1] としています。

※ 今回はボタンは使用しません。バグのためかフォーム上のボタンをクリックしてもイベントが開始しませんでした。

ユーザーフォーム上に JV-Link を配置します。
オブジェクト名はデフォルトの [JVLink1] としています。
※ JV-Link は実行時に表示されないので、レイアウトを気にする必要はありません。

[コードの表示] ボタンをクリックします。

コードエディタが開きます。

下記コードを入力します。

Friend Sub GetRaceInfo()
    Dim sid As String
    Dim retval As Long
    Dim buff As String
    Dim filename As String
    Dim racename As String
    Dim racenames As String

    sid = "UNKNOWN"

    'JVLinkを初期化
    JVLink1.JVInit (sid)

    '速報系データの0B12を呼び出し
    '日付は直近の土日を指定して下さい
    retval = JVLink1.JVRTOpen("0B15", "20230430")

    'JVRTOpenエラー処理
    If (retval < 0) Then
        MsgBox ("JVRTOpenエラー。RC=" & retval)
        GoTo CommandButton1_END
    End If

    retval = 1
    While retval <> 0
        'JVRTOpenで指定したデータを１レコードずつ取り込み
        retval = JVLink1.JVRead(buff, 1300, filename)
        'JVReadエラー処理
        If (retval < -1) Then
            MsgBox ("JVReadエラー。RC=" & retval)
            GoTo CommandButton1_END
        End If
        If Left(buff, 2) = "RA" Then
            'レース名を抽出し末尾のスペースを除去
            racename = RTrim(Right(Left(buff, 62), 30))
            'レース名が空文字でなければレース名一覧に結合
            If racename <> "" Then
                racenames = racenames & racename & vbCrLf
            End If
        End If
    Wend
    'レース名一覧を表示
    MsgBox (racenames)

CommandButton1_END:

    '一通り読み込みが終わった後はJVCloseを行う
    JVLink1.JVClose

End Sub

※ プロシージャのスコープは Private ではなく Friend にしてあります。ボタンが使えないので標準モジュールから呼び出せるようにするためです。
※ While ステートメント最後の DoEvents 関数は除去してあります。残したままだとバグのためか処理が固まってしまいました。

16 行目の

    retval = JVLink1.JVRTOpen("0B15", "20230430")

の日付部分は直近の土日（中央競馬のレースが開催された日）を yyyymmdd 形式で指定して下さい。
※ このコードで取得している速報系データはレース後 1 週間程で配信されなくなるので、古い開催日を指定してもデータは取得できません。

[挿入] > [標準モジュール] をクリックします。

標準モジュールが追加されます。

コードエディタに下記コードを入力します。

Private Sub macro1()
    Call UserForm1.GetRaceInfo
End Sub

3. 動作確認

Publisher の画面に戻り、[開発] タブの [マクロ] をクリックします。

マクロ画面が表示されたら、macro1 が選択されていることを確認し [実行] ボタンをクリックします。

メッセージボックスにレース名が表示されれば OK です。

レース開催が無い日や、古い開催日をコード内で指定している場合は下図のようなエラーが発生します。