【Unity】Line Rendererで破線を引く

Hiko

2021年1月30日 16:05

破線の利用頻度は多いイメージですが、意外とUnityで簡単に行う方法が見つからなかったため備忘録も兼ねて解説します。

方法としてはアセットや画像は使わず、Unityの基本機能であるLine RendererとShaderを使って実現します。

１．Line Rendererの設置

まずはヒエラルキーにEmpty Objectを作成し、Line Rendererコンポーネントをアタッチします。例ではGameObjectにLinerenderという名前を付けています。

２．Line Renderの設定

ひとまず線がよく見えるようにLine Rederer設定のPositionsに適当な値を入れてください。例ではIndex 1にX=10, Y=10, Z=10を入れています。

Width(幅)もお好みの設定で構いませんが、太すぎたり細すぎたりするとやはり分かりづらいため、まずは例のように0.1程度に設定します。

最後にTexture ModeをTileに設定してください。これから設定するマテリアル(Texture)をTile状にすることで破線を表現していきます。

ここまで設定するとSceneが以下のようになります。ビューの位置は見やすいように移動してください。まだマテリアルを設定していないためLine Renderはピンク色になっています。

３．Shaderの作成

エディタ上のProjectパネルで右クリックし、[Create] > [Shader] > [Unlit Shader]を選択します。名前は「DashLine」とします。

４．マテリアルの作成

作成したShaderを選択した状態で右クリックし、[Create] > [Material]を選択します。名前はShaderと同じように「DashLine」とします。選択した状態で作成することでShaderとマテリアルが紐づけられます。

５．Shaderの記述

作成したShaderをダブルクリックし、以下のコードを貼り付けて保存します。(2021.02.19) 色変更できるようにコードを修正しました。

Shader "Unlit/DashLine"
{
   Properties {
       _MainTex ("Texture", 2D) = "white" {}
       _Color ("Color", Color) = (1,1,1,1)
       _Rate ("Rate", Range(0, 1)) = 0.5
   }
   SubShader {
       Tags { "RenderType"="Transparent" "Queue" = "Transparent" }
       Blend SrcAlpha OneMinusSrcAlpha 
       LOD 100

       Pass {
           CGPROGRAM
           #pragma vertex vert
           #pragma fragment frag

           #include "UnityCG.cginc"

           struct appdata {
               float4 vertex : POSITION;
               float2 uv : TEXCOORD0;
           };

           struct v2f {
               float2 uv : TEXCOORD0;
               float4 vertex : SV_POSITION;
           };

           sampler2D _MainTex;
           float4 _MainTex_ST;
           float _Rate;
           fixed4 _Color;

           v2f vert (appdata v) {
               v2f o;
               o.vertex = UnityObjectToClipPos(v.vertex);
               o.uv = TRANSFORM_TEX(v.uv, _MainTex);
               return o;
           }

           fixed4 frag (v2f i) : SV_Target {
               return step(_Rate, frac(i.uv.x)) * _Color;
           }
           ENDCG
       }
   }
}