AppleScriptでつくる爆速始業/終業報告

葛原健太//クズケン

2023年7月6日 16:13

ウヴォーさん、聞こえますか。今回の記事は、最近上長へのメールでの始業/終業報告が必須になったという某大手広告会社の皆様への俺からの鎮魂歌（レクイエム）です。

AppleScriptってやつを使いますが、プログラミング知識不要で、15分あればできると思うので非エンジニアでもぜひやってみてください。

動作の様子

設定したメールアドレスに、設定したメッセージを送るスクリプトを実行している様子です。３クリックで報告が終わります。
いちいちメーラー立ち上げて、宛先入れて、タイトルと本文いれて・・・に比べると圧倒的に楽なはず。

STEP.01 AppleScriptを開く

ApplicationのなかのUtilityフォルダに鎮座している、埃まみれのAppleScriptを立ち上げましょう。

STEP.02 コードをコピペする

ファイル＞新規 で、新しいファイルを作って、以下のコードをコピペしてください。

-- 各自の環境にあわせて最初に設定してください
set recipientAddress to "XXX@gmail.com" --報告する上長のアドレス
set recipientName to "山田" --上長の名前
set senderName to "佐藤" --自分の名前
set startMessage to "これから始業いたします！" --メール本文：始業時
set endMessage to "終業いたします！" -- メール本文：終業時

-- ダイアログボックスを表示してユーザーから入力を得る
display dialog "何の報告をしますか？" buttons {"キャンセル", "終業", "始業"} default button "始業"
set theButton to button returned of result

-- 報告の種類に応じてメールの件名と内容を設定する
if theButton is "始業" then
	set theSubject to "【" & senderName & "】始業報告"
	set theContent to recipientName & "様、" & startMessage
else if theButton is "終業" then
	set theSubject to "【" & senderName & "】終業報告"
	set theContent to recipientName & "様、" & endMessage
else
	return -- ユーザーが「キャンセル」を選択した場合は何もしない
end if

-- メールを作成して送信する
tell application "Mail"
	set myMessage to make new outgoing message with properties {subject:theSubject, content:theContent, visible:true}
	tell myMessage
		make new to recipient at end of to recipients with properties {address:recipientAddress}
	end tell
	send myMessage
end tell

冒頭にある各自の環境にあわせて設定する部分は、右側のメモの通りなので自分なりに設定してください。
アプリ右上の再生ボタン▶️で実行可能です（⌘＋Rでも）
これを実行すると
・ダイアログボックスが立ち上がる
・始業か終業かを選ぶ
・メールが飛ぶ（※Macデフォルトのメーラーソフトを使っていない人は、アカウント設定が必要です）
という流れで動きます。
最初はテストとして、送信先アドレスを自分のプライベートアドレスなどを設定するのがおすすめです。

STEP.03 実行しやすくする

毎日使うとなると、実行しやすくしたいですよね。ということで、以下手順です（ChatGPTさんに書いてもらいました）

🌻 メニューバーから実行できるようにする方法
その１：スクリプトメニューの有効化

Script EditorのメニューバーからScript Editor > Preferences（または環境設定）を選択します。
開いた環境設定の中で、Show Script menu in menu bar（またはスクリプトメニューをメニューバーに表示）にチェックを入れます。

これで、メニューバーの右上にスクリプトのアイコンが表示され、スクリプトメニューが有効になります。

その2：スクリプトの保存

スクリプトエディタで、実行したいAppleScriptを書きます。
File > Save（またはファイル > 保存）を選択します。
Save As（または名前をつけて保存）のフィールドにスクリプトの名前を入力します。
File Format（または フォーマット）でScript を選択します。
Where（または 保存場所）で、/Users/[YourName]/Library/Scripts（[YourName] はあなたのユーザー名に置き換えてください）を選択します。もしこのフォルダが存在しない場合は、新しく作成してください。あるいは、不可視フォルダになっている場合もあるので、隠しファイルも表示する Shift+Command+. を押してみてください。
Save（または保存）ボタンをクリックします。

これでスクリプトが保存され、スクリプトメニューから呼び出せるようになります。

その３：スクリプトの実行

メニューバーのスクリプトアイコンをクリックします。
ドロップダウンメニューから、作成したスクリプトを選択します。

これでスクリプトが実行されます。

以上、始業・終業報告を秒で終わらせる方法でした。めんどくさいですね、始業・終業報告。