ボリンジャーバンド ×3 インジケーター(アラート機能付き)【TradingView】
スクリーンショット_2018-11-28_17_52_16

ボリンジャーバンド ×3 インジケーター(アラート機能付き)【TradingView】

まっつ(TORYS)@matsu_bitmex
更新履歴
2019/12/29 EMA/SMMA切り替え対応


無料で使えるボリンジャーバンド×3(アラート機能付き)インディケーターを公開しました。


こんにちは、まっつ@matsu_bitmexです。ボリンジャーバンドタッチでアラートがでるインジを公開しました。

TradingViewにて「Bollinger Bands with Alert」と検索してもらえると使えます。


いたって普通のボリバンです。

画像1

ボリバンを複数使ってる人はインジの数が節約できるかと。


設定こんなかんじ。

画像2

・BB for Alert Number・・・BB1〜3、どれにタッチでアラートが出るか選択できます。

・BB Upper Cross Source・・・上側にタッチするソースを選択できます。

・BB Lower Cross Source・・・下側にタッチするソースを選択できます。

・Cross Select・・・ボリバンの外側にいった時にアラートを出すのか、内側に戻ってきた時にアラートを出すのか選択できます。


画像3

たぶんこんな感じでアラート出せます。TradingView無料会員の方はアラート1つしか設定できない、とのことで1つのアラートで上側タッチも下側タッチも鳴るようにしました。


- - - 2019/12/29 追記 - - -

スクリーンショット 2019-12-29 15.41.03

センターラインの SMA / EMA / SMMA 切り替え対応しました。

- - - 追記ここまで - - -

- - - 2019/12/31 追記 - - -

スクリーンショット 2019-12-31 0.15.51

BB 1-2 / 2-3 の fill 表示に対応しました。上の画像は fill 2-3 (BB 2-3 の間を着色)です。

- - - 追記ここまで - - -


最後にソースコードはこちら。

//@version=3
study(shorttitle="BB Alert", title="Bollinger Bands with Alert", overlay=true)

//input
length = input(20, minval=1, title="SMA length")
src = input(close, title="Source")
ma_select = input("SMA", "MA select", options=["SMA", "EMA", "SMMA"])

mult1 = input(1.0, minval=0.001, maxval=50, title="BB1 mult")
mult2 = input(2.0, minval=0.001, maxval=50, title="BB2 mult")
mult3 = input(3.0, minval=0.001, maxval=50, title="BB3 mult")
bb1 = input(true, title="display BB1")
bb2 = input(true, title="display BB2")
bb3 = input(true, title="display BB3")
alert = input(2, minval=1, maxval=3, title="BB for alert number")
upper_src = input(high, title="BB uppper cross source")
lower_src = input(low, title="BB lower cross source")
cross_select = input("Outside", options=["Outside", "Inside"], title="cross select")

//MA
smma = 0.0
smma := na(smma[1]) ? sma(src, length) : (smma[1] * (length - 1) + src) / length
basis = ma_select=="EMA" ? ema(src, length) : ma_select=="SMA" ? sma(src, length) : smma


//BB3
dev3 = mult3 * stdev(src, length)
upper3 = basis + dev3
lower3 = basis - dev3
p5 = plot(bb3 ? upper3 : na, color=blue, title="upper 3")
p6 = plot(bb3 ? lower3 : na, color=blue, title="lower 3")

//BB2
dev2 = mult2 * stdev(src, length)
upper2 = basis + dev2
lower2 = basis - dev2
p3 = plot(bb2 ? upper2 : na, color=blue, title="upper 2")
p4 = plot(bb2 ? lower2 : na, color=blue, title="upper 2")

//BB1
dev1 = mult1 * stdev(src, length)
upper1 = basis + dev1
lower1 = basis - dev1
p1 = plot(bb1 ? upper1 : na, color=blue, title="upper 1")
p2 = plot(bb1 ? lower1 : na, color=blue, title="lower 1")

//fill
fill(p1, p2, color=silver, title="fill BB1")
fill(p3, p4, color=silver, title="fill BB2")
fill(p5, p6, color=silver, title="fill BB3")

fill(p1, p3, silver, title="fill BB upper 1-2")
fill(p2, p4, silver, title="fill BB lower 1-2")
fill(p3, p5, silver, title="fill BB upper 2-3")
fill(p4, p6, silver, title="fill BB lower 2-3")

plot(basis, color=red, title="SMA")

upper = alert == 1 ? upper1 : alert == 2 ? upper2 : upper3
lower = alert == 1 ? lower1 : alert == 2 ? lower2 : lower3
upper_cross = cross_select == "Outside" ? crossover(upper_src, upper) : crossunder(upper_src, upper)
lower_cross = cross_select == "Outside" ? crossunder(lower_src, lower) : crossover(lower_src, lower)

alertcondition(upper_cross or lower_cross, title="Alert BB Cross", message="Alert BB Cross")


というわけで、簡単にですがボリバン×3 &アラートインジの紹介でした。

よかったらnoteのフォロー/スキお願いします。ではまた!

この記事が気に入ったら、サポートをしてみませんか?
気軽にクリエイターの支援と、記事のオススメができます!
スキありがとうございます!
まっつ(TORYS)@matsu_bitmex
Tradingview Pine スクリプトで開発やってます。BTCFX/為替で使えるインディケーター公開中。noteは有料にしてますがインジは全て無料で使用可能。ぜひ使ってみてください。インジ制作のご相談お気軽に。※ 連絡はTwitter DMでお願いします ※