Twitter推奨のサイズにアイコンをリサイズするbat作りました【FFmpeg×Windows bat】

あらすじ

アイコンを設定したけどなんかボヤけてる（えぇ）…原因はアップロードしたアイコンが勝手に縮小されてるからかも（ぴえん）…どうしよう（困惑）…せや、事前に縮小すれば勝手に縮小されずに綺麗な画質を維持できるかもしれない（天才）

これは何？

800x800px以上の正方形画像を下記のbatファイルにD&DするとDiscord, Google, Microsoft, Twitterの推奨サイズでアイコン画像を生成してくれます。
FFmpeg（環境変数PATH追加済み）が導入されているWindows上で動きます。

IconPictureResize.bat

@echo off
rem ドラッグアンドドロップしたファイルをカレントディレクトリにする
cd /d %~dp1
rem 出力ファイル名（入力ファイルと同じディレクトリに出力する。フルパス。）
set outputPicture=%~dpn1
rem 入力ファイル名（フルパス）
set inputPicture=%~dpnx1
call :EXPLANATION
if "%1"=="" (
   pause
   exit
) else (
   call :DISCORD
   call :GOOGLE
   call :MICROSOFT
   call :TWITTER
   echo 完了しました。元ファイルと同じフォルダーを確認してください。
   pause
   exit
)
:DISCORD
ffmpeg ^
-i "%inputPicture%" ^
-vf "scale=if(gte(iw\,ih)\,min(128\,iw)\,-2):if(lt(iw\,ih)\,min(128\,ih)\,-2):flags=lanczos+accurate_rnd" ^
-qmin 1 ^
-q 1 ^
"%outputPicture%_dsc.png"
exit /b
:GOOGLE
ffmpeg ^
-i "%inputPicture%" ^
-vf "scale=if(gte(iw\,ih)\,min(800\,iw)\,-2):if(lt(iw\,ih)\,min(800\,ih)\,-2):flags=lanczos+accurate_rnd" ^
-qmin 1 ^
-q 1 ^
"%outputPicture%_ggl.png"
exit /b
:MICROSOFT
ffmpeg ^
-i "%inputPicture%" ^
-vf "scale=if(gte(iw\,ih)\,min(448\,iw)\,-2):if(lt(iw\,ih)\,min(448\,ih)\,-2):flags=lanczos+accurate_rnd" ^
-qmin 1 ^
-q 1 ^
"%outputPicture%_ms.png"
exit /b
:TWITTER
ffmpeg ^
-i "%inputPicture%" ^
-vf "scale=if(gte(iw\,ih)\,min(400\,iw)\,-2):if(lt(iw\,ih)\,min(400\,ih)\,-2):flags=lanczos+accurate_rnd" ^
-qmin 1 ^
-q 1 ^
"%outputPicture%_tw.png"
exit /b
:EXPLANATION
echo ----------------------------------------------------------------------
echo ■このファイルの目的
echo 各サービス用のアイコン画像を作成します。
echo "dsc->Discord, ggl->Google, ms->Microsoft, tw->Twitter"
echo.
echo ■動作環境
echo FFmpeg（環境変数PATH追加済み）が動作するWindows
echo.
echo ■使い方
echo 1. 800x800px以上の正方形の画像を用意（例：1600x1600px）
echo 2. リサイズしたいファイルをこのバッチファイルにドラッグ＆ドロップ
echo ----------------------------------------------------------------------
exit /b

メモ

・縮小アルゴリズムに万能と評判のlanczos+accurate_rndを使用しています。
・800x800pxよりも小さい解像度の画像を元にした場合、正しく動作しないことがあります。

あとがき

（意外とアイコン使う場所なくない！？）